1# Copyright (c) 2021-2024 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("//foundation/arkui/ace_engine/ace_config.gni")
16import("//foundation/arkui/ace_engine/build/ace_ext.gni")
17
18# build static
19template("ace_osal_ohos_source_set") {
20  forward_variables_from(invoker, "*")
21
22  ohos_source_set(target_name) {
23    subsystem_name = ace_engine_subsystem
24    part_name = ace_engine_part
25    defines += invoker.defines
26    if (defined(vendor_configs.use_ext_surface) &&
27        vendor_configs.use_ext_surface) {
28      defines += [ "EXT_SURFACE_ENABLE" ]
29    }
30    if (is_ohos_standard_system) {
31      external_deps = [
32        "hilog:libhilog",
33        "hitrace:hitrace_meter",
34        "imf:inputmethod_client",
35        "init:libbeget_proxy",
36        "init:libbegetutil",
37      ]
38      configs = [ "$ace_root:ace_config" ]
39    } else {
40      external_deps = [
41        "hilog:libhilog",
42        "hitrace:hitrace_meter",
43        "init:libbegetutil",
44      ]
45
46      configs = [ "$ace_root:ace_config" ]
47    }
48
49    sources = [
50      "ace_checker.cpp",
51      "ace_engine_ext.cpp",
52      "ace_trace.cpp",
53      "ai_write_adapter.cpp",
54      "anr_thread.cpp",
55      "app_bar_helper_impl.cpp",
56      "data_detector_adapter.cpp",
57      "data_detector_loader.cpp",
58      "data_detector_mgr.cpp",
59      "display_info_utils.cpp",
60      "download_manager_ohos.cpp",
61      "event_report.cpp",
62      "exception_handler.cpp",
63      "frame_report.cpp",
64      "image_analyzer_adapter_impl.cpp",
65      "image_analyzer_loader.cpp",
66      "image_analyzer_manager.cpp",
67      "image_analyzer_mgr.cpp",
68      "input_method_manager_ohos.cpp",
69      "layout_inspector.cpp",
70      "log_wrapper.cpp",
71      "modal_ui_extension_impl.cpp",
72      "ressched_report.cpp",
73      "socperf_client_impl.cpp",
74      "stylus_detector_callback.cpp",
75      "stylus_detector_default.cpp",
76      "stylus_detector_loader.cpp",
77      "stylus_detector_mgr.cpp",
78      "system_properties.cpp",
79      "thp_extra_manager_impl.cpp",
80      "thread_priority.cpp",
81      "trace_id_impl.cpp",
82      "view_data_wrap_ohos.cpp",
83      "want_wrap_ohos.cpp",
84      "window_utils.cpp",
85    ]
86
87    external_deps += [
88      "ability_runtime:app_manager",
89      "i18n:intl_util",
90      "init:libbegetutil",
91    ]
92
93    if (is_ohos_standard_system) {
94      sources += [
95        "resource_adapter_impl.cpp",
96        "resource_adapter_impl_v2.cpp",
97        "resource_convertor.cpp",
98        "resource_theme_style.cpp",
99      ]
100      deps = []
101
102      if (defined(global_parts_info) &&
103          defined(global_parts_info.resourceschedule_soc_perf)) {
104        external_deps += [ "soc_perf:socperf_client" ]
105        defines += [ "SOC_PERF_ENABLE" ]
106      }
107
108      if (defined(global_parts_info) && defined(
109              global_parts_info.resourceschedule_resource_schedule_service)) {
110        external_deps += [ "resource_schedule_service:ressched_client" ]
111        defines += [ "RESOURCE_SCHEDULE_SERVICE_ENABLE" ]
112      }
113
114      if (defined(resourceschedule_ffrt_support) &&
115          resourceschedule_ffrt_support) {
116        sources += [ "long_frame_report_impl.cpp" ]
117        external_deps += [ "ffrt:libffrt" ]
118      }
119
120      external_deps += [
121        "ability_base:view_data",
122        "ability_base:want",
123        "ability_runtime:abilitykit_native",
124        "graphic_2d:libframe_analyzer",
125        "image_framework:image",
126        "input:libmmi-client",
127        "napi:ace_napi",
128        "resource_management:global_resmgr",
129      ]
130      if (defined(config.accessibility_support) &&
131          config.accessibility_support) {
132        sources += [
133          "js_accessibility_manager.cpp",
134          "js_third_accessibility_hover_ng.cpp",
135          "js_third_provider_interaction_operation.cpp",
136        ]
137        deps += [ "$ace_root/frameworks/bridge/common/accessibility:bridge_accessibility_$platform" ]
138        external_deps += [
139          "accessibility:accessibility_common",
140          "accessibility:accessibilityclient",
141          "accessibility:accessibilityconfig",
142        ]
143      } else {
144        sources += [ "fake_accessibility_manager.cpp" ]
145      }
146      if (frame_trace_support) {
147        sources += [ "frame_trace_adapter_impl.cpp" ]
148        external_deps += [ "frame_aware_sched:frame_trace_intf" ]
149        defines += [ "FRAME_TRACE_ENABLE" ]
150      } else {
151        sources += [ "frame_trace_adapter_fake_impl.cpp" ]
152      }
153    } else {
154      external_deps += [ "multimedia_image:image" ]
155    }
156    sources += [
157      "background_task_helper_ohos.cpp",
158      "drawing_color_filter_ohos.cpp",
159      "drawing_lattice_ohos.cpp",
160      "file_uri_helper_ohos.cpp",
161      "image_packer_ohos.cpp",
162      "image_source_ohos.cpp",
163      "input_manager.cpp",
164      "mouse_style_ohos.cpp",
165      "navigation_route_ohos.cpp",
166      "page_url_checker_ohos.cpp",
167      "pixel_map_ohos.cpp",
168      "system_bar_style_ohos.cpp",
169    ]
170    external_deps += [
171      "ability_runtime:abilitykit_native",
172      "ability_runtime:app_manager",
173      "ability_runtime:wantagent_innerkits",
174      "app_file_service:fileuri_native",
175      "background_task_mgr:bgtaskmgr_innerkits",
176      "bundle_framework:appexecfwk_core",
177      "graphic_2d:2d_graphics",
178      "graphic_2d:drawing_napi_impl",
179      "graphic_2d:librender_service_client",
180      "hicollie:libhicollie",
181      "hisysevent:libhisysevent",
182      "hitrace:libhitracechain",
183      "safwk:system_ability_fwk",
184      "samgr:samgr_proxy",
185      "window_manager:libdm",
186      "window_manager:libwm",
187      "window_manager:scene_session",
188      "window_manager:window_native_kit",
189    ]
190
191    if (defined(config.hichecker_exists) && config.hichecker_exists) {
192      external_deps += [ "hichecker:libhichecker" ]
193    }
194    deps += [
195      "$ace_root/interfaces/inner_api/drawable_descriptor:drawable_descriptor",
196    ]
197
198    if (ability_runtime_graphics) {
199      external_deps += [ "image_framework:image_native" ]
200    }
201  }
202}
203
204foreach(item, ace_platforms) {
205  platform = item.name
206  if (platform == "ohos" || platform == "ohos_ng") {
207    ace_osal_ohos_source_set("ace_osal_ohos_${platform}") {
208      platform = item.name
209      assert(defined(platform) && platform != "", "platform must be defined")
210      defines = []
211      config = {
212      }
213
214      if (defined(item.config)) {
215        config = item.config
216      }
217      if (defined(config.defines)) {
218        defines = config.defines
219      }
220    }
221  }
222}
223