1# Copyright (c) 2022 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("../config.gni")
16
17config("ohos_adapter_public_interface") {
18  include_dirs = [ "interfaces" ]
19}
20
21ohos_shared_library("nweb_ohos_adapter") {
22  output_name = "arkweb_os_adapter"
23
24  if (target_cpu == "arm64") {
25    branch_protector_ret = "pac_ret"
26    branch_protector_frt = "bti"
27  }
28
29  defines = [
30    "HILOG_TAG=\"webadapter\"",
31    "WEBVIEW_PACKAGE_NAME=\"${webview_package_name}\"",
32    "WEBVIEW_SANDBOX_LIB_PATH=\"${webview_sandbox_lib_path}\"",
33    "WEBVIEW_CRASHPAD_HANDLER_SO=\"${webview_crashpad_handler_so}\"",
34    "WEBVIEW_SANDBOX_RELATIVE_LIB_PATH=\"${webview_sandbox_relative_lib_path}\"",
35    "WEBVIEW_ENGINE_SO=\"${webview_engine_so}\"",
36    "WEBVIEW_SANDBOX_HAP_PATH=\"${webview_sandbox_hap_path}\"",
37    "WEBVIEW_APP_HAP_PATH=\"${webview_app_hap_path}\"",
38    "WEBVIEW_APP_HAP_PATH2=\"${webview_app_hap_path2}\"",
39    "WEBVIEW_HAP_PATH=\"${webview_hap_path}\"",
40    "WEBVIEW_SANDBOX_PATH=\"${webview_sandbox_path}\"",
41  ]
42
43  sources = [
44    "aafwk_adapter/src/aafwk_app_mgr_client_adapter_impl.cpp",
45    "aafwk_adapter/src/aafwk_browser_client_adapter_impl.cpp",
46    "aafwk_adapter/src/aafwk_browser_host_impl.cpp",
47    "aafwk_adapter/src/aafwk_render_scheduler_impl.cpp",
48    "access_token_adapter/src/access_token_adapter_impl.cpp",
49    "background_task_adapter/src/background_task_impl.cpp",
50    "cert_mgr_adapter/src/cert_mgr_adapter_impl.cpp",
51    "datashare_adapter/src/datashare_adapter_impl.cpp",
52    "date_time_format_adapter/src/date_time_format_adapter_impl.cpp",
53    "display_manager_adapter/src/display_manager_adapter_impl.cpp",
54    "distributeddatamgr_adapter/webdatabase/src/ohos_web_data_base_adapter_impl.cpp",
55    "distributeddatamgr_adapter/webdatabase/src/ohos_web_permission_data_base_adapter_impl.cpp",
56    "enterprise_device_management_adapter/src/enterprise_device_management_adapter_impl.cpp",
57    "event_handler_adapter/src/event_handler_adapter_impl.cpp",
58    "flowbuffer_adapter/src/flowbuffer_adapter_impl.cpp",
59    "graphic_adapter/src/ashmem_adapter_impl.cpp",
60    "graphic_adapter/src/native_image_adapter_impl.cpp",
61    "graphic_adapter/src/surface_adapter_impl.cpp",
62    "graphic_adapter/src/vsync_adapter_impl.cpp",
63    "graphic_adapter/src/window_adapter_impl.cpp",
64    "hiviewdfx_adapter/src/hilog_adapter.cpp",
65    "hiviewdfx_adapter/src/hisysevent_adapter_impl.cpp",
66    "hiviewdfx_adapter/src/hitrace_adapter_impl.cpp",
67    "inputmethodframework_adapter/src/imf_adapter_impl.cpp",
68    "keystore_adapter/src/keystore_adapter_impl.cpp",
69    "multimodalinput_adapter/src/mmi_adapter_impl.cpp",
70    "net_proxy_adapter/src/net_proxy_adapter_impl.cpp",
71    "ohos_adapter_helper/src/ohos_adapter_helper_impl.cpp",
72    "ohos_image_adapter/src/ohos_image_decoder_adapter_impl.cpp",
73    "ohos_init_web_adapter/src/ohos_init_web_adapter_impl.cpp",
74    "ohos_native_buffer_adapter/src/ohos_native_buffer_adapter_impl.cpp",
75    "ohos_resource_adapter/src/ohos_resource_adapter_impl.cpp",
76    "pasteboard_adapter/src/pasteboard_client_adapter_impl.cpp",
77    "print_manager_adapter/src/print_manager_adapter_impl.cpp",
78    "res_sched_adapter/src/res_sched_client_adapter_impl.cpp",
79    "soc_perf_adapter/src/soc_perf_client_adapter_impl.cpp",
80    "system_properties_adapter/src/system_properties_adapter_impl.cpp",
81  ]
82
83  cflags = [
84    "-Wall",
85    "-Werror",
86    "-g3",
87  ]
88
89  include_dirs = [
90    "../ohos_nweb/include",
91    "aafwk_adapter/include",
92    "access_token_adapter/include",
93    "audio_adapter/include",
94    "battery_mgr_adapter/include",
95    "camera_adapter/include",
96    "cert_mgr_adapter/include",
97    "datashare_adapter/include",
98    "date_time_format_adapter/include",
99    "display_manager_adapter/include",
100    "distributeddatamgr_adapter/webdatabase/include",
101    "enterprise_device_management_adapter/include",
102    "event_handler_adapter/include",
103    "flowbuffer_adapter/include",
104    "graphic_adapter/include",
105    "hiviewdfx_adapter/include",
106    "inputmethodframework_adapter/include",
107    "keystore_adapter/include",
108    "location_adapter/include",
109    "media_adapter/include",
110    "multimodalinput_adapter/include",
111    "net_connect_adapter/include",
112    "net_proxy_adapter/include",
113    "ohos_adapter_helper/include",
114    "ohos_image_adapter/include",
115    "ohos_init_web_adapter/include",
116    "ohos_native_buffer_adapter/include",
117    "ohos_resource_adapter/include",
118    "pasteboard_adapter/include",
119    "power_mgr_adapter/include",
120    "print_manager_adapter/include",
121    "screen_capture_adapter/include",
122    "soc_perf_adapter/include",
123    "system_properties_adapter/include",
124    "sensor_adapter/include",
125  ]
126
127  public_configs = [ ":ohos_adapter_public_interface" ]
128
129  external_deps = [
130    "ability_base:extractortool",
131    "ability_base:want",
132    "ability_base:zuri",
133    "ability_runtime:ability_manager",
134    "ability_runtime:abilitykit_native",
135    "ability_runtime:app_context",
136    "ability_runtime:app_manager",
137    "access_token:libaccesstoken_sdk",
138    "app_file_service:fileuri_native",
139    "background_task_mgr:bgtaskmgr_innerkits",
140    "bundle_framework:appexecfwk_base",
141    "bundle_framework:appexecfwk_core",
142    "c_utils:utils",
143    "certificate_manager:cert_manager_sdk",
144    "common_event_service:cesfwk_innerkits",
145    "data_share:datashare_common",
146    "data_share:datashare_consumer",
147    "eventhandler:libeventhandler",
148    "file_api:remote_uri_native",
149    "graphic_2d:libcomposer",
150    "graphic_2d:libnative_image",
151    "graphic_2d:librender_service_client",
152    "graphic_surface:surface",
153    "hilog:libhilog",
154    "hisysevent:libhisysevent",
155    "hitrace:hitrace_meter",
156    "huks:libhukssdk",
157    "i18n:intl_util",
158    "image_framework:image_native",
159    "imf:inputmethod_client",
160    "init:libbeget_proxy",
161    "init:libbegetutil",
162    "input:libmmi-client",
163    "ipc:ipc_core",
164    "napi:ace_napi",
165    "netmanager_base:net_conn_manager_if",
166    "pasteboard:pasteboard_client",
167    "relational_store:native_rdb",
168    "resource_schedule_service:ressched_client",
169    "samgr:samgr_proxy",
170    "time_service:time_client",
171    "window_manager:libdm",
172    "window_manager:libdm_ndk",
173  ]
174
175  if (webview_soc_perf_enable) {
176    external_deps += [ "soc_perf:socperf_client" ]
177    defines += [ "NWEB_SOC_PERF" ]
178  }
179
180  if (webview_audio_enable) {
181    sources += [
182      "audio_adapter/src/audio_capturer_adapter_impl.cpp",
183      "audio_adapter/src/audio_device_desc_adapter_impl.cpp",
184      "audio_adapter/src/audio_renderer_adapter_impl.cpp",
185      "audio_adapter/src/audio_system_manager_adapter_impl.cpp",
186    ]
187    external_deps += [
188      "audio_framework:audio_capturer",
189      "audio_framework:audio_client",
190      "audio_framework:audio_renderer",
191    ]
192    defines += [ "NWEB_AUDIO_ENABLE" ]
193  } else {
194    sources += [
195      "audio_adapter/src/audio_capturer_adapter_mock.cpp",
196      "audio_adapter/src/audio_device_desc_adapter_mock.cpp",
197      "audio_adapter/src/audio_renderer_adapter_mock.cpp",
198      "audio_adapter/src/audio_system_manager_adapter_mock.cpp",
199    ]
200  }
201
202  if (webview_location_enable) {
203    sources += [
204      "location_adapter/src/location_callback_adapter_impl.cpp",
205      "location_adapter/src/location_instance_impl.cpp",
206      "location_adapter/src/location_proxy_adapter_impl.cpp",
207    ]
208    external_deps += [
209      "location:lbsservice_common",
210      "location:locator_sdk",
211    ]
212    defines += [ "NWEB_LOCATION_ENABLE" ]
213  } else {
214    sources += [ "location_adapter/src/location_proxy_adapter_mock.cpp" ]
215  }
216
217  if (webview_avcodec_enable) {
218    sources += [
219      "media_adapter/src/buffer_info_adapter_impl.cpp",
220      "media_adapter/src/capability_data_adapter_impl.cpp",
221      "media_adapter/src/codec_format_adapter_impl.cpp",
222      "media_adapter/src/media_codec_decoder_adapter_impl.cpp",
223      "media_adapter/src/media_codec_encoder_adapter_impl.cpp",
224      "media_adapter/src/media_codec_list_adapter_impl.cpp",
225      "media_adapter/src/ohos_buffer_adapter_impl.cpp",
226    ]
227    external_deps += [
228      "av_codec:av_codec_client",
229      "media_foundation:media_foundation",
230    ]
231    defines += [ "NWEB_MEDIA_AVCODEC_ENABLE" ]
232  } else {
233    sources += [ "media_adapter/src/media_codec_list_adapter_mock.cpp" ]
234  }
235
236  if (webview_media_player_enable) {
237    sources += [ "media_adapter/src/player_framework_adapter_impl.cpp" ]
238    external_deps += [ "player_framework:media_client" ]
239    defines += [ "NWEB_MEDIA_PLAYER_ENABLE" ]
240  }
241
242  if (webview_camera_enable) {
243    sources += [
244      "camera_adapter/src/camera_manager_adapter_impl.cpp",
245      "camera_adapter/src/camera_rotation_info_adapter_impl.cpp",
246      "camera_adapter/src/format_adapter_impl.cpp",
247      "camera_adapter/src/video_capture_range_adapter_impl.cpp",
248      "camera_adapter/src/video_control_support_adapter_impl.cpp",
249      "camera_adapter/src/video_device_descriptor_adapter_impl.cpp",
250      "screen_capture_adapter/src/screen_capture_adapter_impl.cpp",
251    ]
252    external_deps += [ "camera_framework:camera_framework" ]
253    defines += [ "NWEB_CAMERA_ENABLE" ]
254  } else {
255    sources += [
256      "camera_adapter/src/camera_manager_adapter_mock.cpp",
257      "camera_adapter/src/camera_rotation_info_adapter_mock.cpp",
258      "camera_adapter/src/format_adapter_mock.cpp",
259      "camera_adapter/src/video_capture_range_adapter_mock.cpp",
260      "camera_adapter/src/video_control_support_adapter_mock.cpp",
261      "camera_adapter/src/video_device_descriptor_adapter_mock.cpp",
262    ]
263  }
264
265  if (webview_telephony_enable) {
266    sources += [
267      "net_connect_adapter/src/net_capabilities_adapter_impl.cpp",
268      "net_connect_adapter/src/net_connect_adapter_impl.cpp",
269      "net_connect_adapter/src/net_connect_callback_impl.cpp",
270      "net_connect_adapter/src/net_connect_utils.cpp",
271      "net_connect_adapter/src/net_connection_properties_adapter_impl.cpp",
272    ]
273    external_deps += [
274      "cellular_data:tel_cellular_data_api",
275      "core_service:tel_core_service_api",
276    ]
277    defines += [ "NWEB_TEL_ENABLE" ]
278  }
279
280  if (webview_battery_manager_enable) {
281    sources += [ "battery_mgr_adapter/src/battery_mgr_client_adapter_impl.cpp" ]
282    external_deps += [ "battery_manager:batterysrv_client" ]
283    defines += [ "NWEB_BATTERY_MANAGER_ENABLE" ]
284  }
285
286  if (webview_power_manager_enable) {
287    sources += [ "power_mgr_adapter/src/power_mgr_client_adapter_impl.cpp" ]
288    external_deps += [ "power_manager:powermgr_client" ]
289    defines += [ "NWEB_POWER_MANAGER_ENABLE" ]
290  }
291
292  if (webview_print_enable) {
293    external_deps += [
294      "print_fwk:print_client",
295      "print_fwk:print_helper",
296      "print_fwk:print_models",
297    ]
298    defines += [ "NWEB_PRINT_ENABLE" ]
299  }
300
301  if (webview_enterprise_device_manager_enable) {
302    external_deps += [ "enterprise_device_management:edmservice_kits" ]
303    defines += [ "NWEB_ENTERPRISE_DEVICE_MANAGER_ENABLE" ]
304  }
305
306  if (webview_media_avsession_enable) {
307    sources += [ "media_adapter/src/media_avsession_adapter_impl.cpp" ]
308    external_deps += [ "av_session:avsession_client" ]
309    defines += [ "NWEB_MEDIA_AVSESSION_ENABLE" ]
310  }
311
312  if (webview_sensors_sensor_enable) {
313    sources += [ "sensor_adapter/src/sensor_adapter_impl.cpp" ]
314    external_deps += [ "sensor:sensor_interface_native" ]
315    defines += [ "NWEB_SENSORS_SENSOR_ENABLE" ]
316  }
317
318  innerapi_tags = [ "platformsdk" ]
319  part_name = "webview"
320  subsystem_name = "web"
321
322  deps = [ "../ohos_nweb:web_configs" ]
323}
324