# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/graphic/graphic_2d/graphic_config.gni")
import("//foundation/graphic/graphic_2d/rosen/modules/effect/effect_config.gni")

## Build libegl_effect.so

config("egl_effect_config") {
  include_dirs = [
    "$graphic_2d_root/utils/log",
    "include",
    "$graphic_2d_root/rosen/modules/effect/effectChain/include",
  ]

  cflags = [
    "-Wall",
    "-Werror",
    "-g3",
    "-Wall",
    "-Wno-pointer-arith",
    "-Wno-non-virtual-dtor",
    "-Wno-missing-field-initializers",
    "-Wno-c++11-narrowing",
  ]

  cflags_cc = [ "-std=c++17" ]
}

if (current_os == "android") {
  ohos_source_set("libegl_effect") {
    configs = [ ":egl_effect_config" ]

    defines = [ "ANDROID_PLATFORM" ]

    include_dirs = [
      "//foundation/multimedia/image_framework/interfaces/innerkits/include",
    ]

    sources = []

    deps = [ "//base/hiviewdfx/hilog/interfaces/native/innerkits:libhilog_${target_os}" ]

    if (effect_enable_gpu) {
      sources += [ "src/egl_manager.cpp" ]
      deps += [
        "$graphic_2d_root/frameworks/opengl_wrapper:EGL",
        "$graphic_2d_root/frameworks/opengl_wrapper:GLESv3",
      ]
    }

    part_name = "graphic_2d"
    subsystem_name = "graphic"
  }
} else {
  ohos_shared_library("libegl_effect") {
    configs = [ ":egl_effect_config" ]
    sources = []
    deps = []
    external_deps = [
      "graphic_surface:surface_headers",
      "hilog:libhilog",
    ]

    if (effect_enable_gpu) {
      sources += [ "src/egl_manager.cpp" ]

      deps += [
        "$graphic_2d_root/frameworks/opengl_wrapper:EGL",
        "$graphic_2d_root/frameworks/opengl_wrapper:GLESv3",
      ]
    }

    if (effect_enable_gpu) {
      install_enable = true
    } else {
      install_enable = false
    }

    part_name = "graphic_2d"
    subsystem_name = "graphic"
  }
}