# Copyright (c) 2021-2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/communication/netmanager_base/netmanager_base_config.gni")
config("netsys_controller_include") {
  include_dirs = [
    "include",
    "$NETSYSNATIVE_SOURCE_DIR/include/netsys",
    "$INNERKITS_ROOT/netstatsclient/include",
  ]

  cflags = [
    "-fstack-protector-strong",
    "-D_FORTIFY_SOURCE=2",
    "-O2",
  ]

  cflags_cc = [
    "-fstack-protector-strong",
    "-D_FORTIFY_SOURCE=2",
    "-O2",
  ]
}

ohos_shared_library("netsys_controller") {
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    boundary_sanitize = true
    ubsan = true
    debug = false
  }

  branch_protector_ret = "pac_ret"

  public_configs = [ ":netsys_controller_include" ]
  sources = [
    "src/mock_netsys_native_client.cpp",
    "src/netsys_controller.cpp",
    "src/netsys_controller_service_impl.cpp",
    "src/netsys_native_client.cpp",
  ]

  include_dirs = [
    "include",
    "$NETCONNMANAGER_SOURCE_DIR/include",
    "$NETCONNMANAGER_COMMON_DIR/include",
    "$NETMANAGER_BASE_ROOT/utils/log/include",
    "$NETSYSNATIVE_INNERKITS_SOURCE_DIR",
    "$INNERKITS_ROOT/netmanagernative/include",
    "$INNERKITS_ROOT/netconnclient/include",
    "$NETMANAGER_BASE_ROOT/utils/common_utils/include",
    "$NETSYSNATIVE_SOURCE_DIR/include/netsys",
    "$NETSYSNATIVE_SOURCE_DIR/include/manager",
  ]

  deps = [
    "$NETMANAGER_BASE_ROOT/services/netmanagernative:netsys_native_manager",
    "$NETMANAGER_BASE_ROOT/utils:net_manager_common",
  ]

  external_deps = [
    "c_utils:utils",
    "ipc:ipc_core",
    "samgr:samgr_proxy",
  ]

  defines = [
    "NETMGR_LOG_TAG = \"NetConnManager\"",
    "LOG_DOMAIN = 0xD0015B0",
  ]

  if (enable_netmgr_debug) {
    defines += [ "NETMGR_DEBUG" ]
  }

  if (enable_sys_func) {
    defines += [ "SYS_FUNC" ]
  }

  if (netmanager_base_enable_feature_net_firewall) {
    defines += [ "FEATURE_NET_FIREWALL_ENABLE" ]
  }

  external_deps += [ "hilog:libhilog" ]

  innerapi_tags = [ "platformsdk_indirect" ]
  part_name = "netmanager_base"
  subsystem_name = "communication"
}